swendel/nixpkgs
1
0
Fork 0
mirror of https://github.com/SebastianWendel/nixpkgs.git synced 2024-09-20 12:29:02 +02:00
Code Issues Packages Projects Releases Wiki Activity

Merge pull request #148098 from zhaofengli/colmena-0.2.0

Browse source 
colmena: init at 0.2.0
This commit is contained in:
0x4A6F 2021-12-06 00:10:57 +01:00 committed by GitHub
parent e1e7c171a2 9c5f93a473
commit 030ff68d47
No known key found for this signature in database
GPG key ID: 4AEE18F83AFDEB23
2 changed files with 44 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

42
pkgs/tools/admin/colmena/default.nix Normal file
View file

@ -0,0 +1,42 @@
{ stdenv, lib, rustPlatform, fetchFromGitHub, installShellFiles, colmena, testVersion }:
rustPlatform.buildRustPackage rec {
pname = "colmena";
version = "0.2.0";
src = fetchFromGitHub {
owner = "zhaofengli";
repo = "colmena";
rev = "v${version}";
sha256 = "sha256-WY8SYapnDcfaoLr1iFgwc9/E7xSfOFN2AvMDpk74AI8=";
};
cargoSha256 = "sha256-ZNSg3hXWKHNQ9yHJS1qW3tFYwzU4ZDa1N0yvoGLmWns=";
nativeBuildInputs = [ installShellFiles ];
postInstall = lib.optionalString (stdenv.hostPlatform == stdenv.buildPlatform) ''
installShellCompletion --cmd colmena \
--bash <($out/bin/colmena gen-completions bash) \
--zsh <($out/bin/colmena gen-completions zsh) \
--fish <($out/bin/colmena gen-completions fish)
'';
# Recursive Nix is not stable yet
doCheck = false;
passthru = {
# We guarantee CLI and Nix API stability for the same minor version
apiVersion = builtins.concatStringsSep "." (lib.take 2 (lib.splitString "." version));
tests.version = testVersion { package = colmena; };
};
meta = with lib; {
description = "A simple, stateless NixOS deployment tool";
homepage = "https://zhaofengli.github.io/colmena/${passthru.apiVersion}";
license = licenses.mit;
maintainers = with maintainers; [ zhaofengli ];
platforms = platforms.linux;
};
}

2
pkgs/top-level/all-packages.nix
View file

@ -277,6 +277,8 @@ with pkgs;
corgi = callPackage ../development/tools/corgi { };
colmena = callPackage ../tools/admin/colmena { };
colobot = callPackage ../games/colobot {};
colorz = callPackage ../tools/misc/colorz { };