From 7d49ffbbe62a821886f0251daf3a3a930d68f4d3 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Maciej=20Kr=C3=BCger?= <mkg20001@gmail.com>
Date: Fri, 4 Jun 2021 08:22:26 +0200
Subject: [PATCH] cinnamon.bulky: init at 1.1

Co-authored-by: Sandro <sandro.jaeckel@gmail.com>
---
 pkgs/desktops/cinnamon/bulky/default.nix | 60 ++++++++++++++++++++++++
 pkgs/desktops/cinnamon/default.nix       |  1 +
 2 files changed, 61 insertions(+)
 create mode 100644 pkgs/desktops/cinnamon/bulky/default.nix

diff --git a/pkgs/desktops/cinnamon/bulky/default.nix b/pkgs/desktops/cinnamon/bulky/default.nix
new file mode 100644
index 000000000000..03b1cca9fd85
--- /dev/null
+++ b/pkgs/desktops/cinnamon/bulky/default.nix
@@ -0,0 +1,60 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, wrapGAppsHook
+, python3
+, gsettings-desktop-schemas
+, gettext
+, gtk3
+, glib
+, common-licenses
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bulky";
+  version = "1.1";
+
+  src = fetchFromGitHub {
+    owner = "linuxmint";
+    repo = "bulky";
+    rev = version;
+    sha256 = "NBlP10IM/+u8IRds4bdFyGWg3pJLRmlSLsdlndMVQqg=";
+  };
+
+  nativeBuildInputs = [
+    wrapGAppsHook
+    gsettings-desktop-schemas
+    gettext
+  ];
+
+  buildInputs = [
+    (python3.withPackages(p: with p; [ pygobject3 magic setproctitle ]))
+    gsettings-desktop-schemas
+    gtk3
+    glib
+  ];
+
+  postPatch = ''
+    substituteInPlace usr/lib/bulky/bulky.py \
+                     --replace "/usr/share/locale" "$out/share/locale" \
+                     --replace /usr/share/bulky "$out/share/bulky" \
+                     --replace /usr/share/common-licenses "${common-licenses}/share/common-licenses" \
+                     --replace __DEB_VERSION__  "${version}"
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    chmod +x usr/share/applications/*
+    cp -ra usr $out
+    ln -sf $out/lib/bulky/bulky.py $out/bin/bulky
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Bulk rename app";
+    homepage = "https://github.com/linuxmint/bulky";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.mkg20001 ];
+  };
+}
diff --git a/pkgs/desktops/cinnamon/default.nix b/pkgs/desktops/cinnamon/default.nix
index 2a52b83f0465..4d148fdcdb0b 100644
--- a/pkgs/desktops/cinnamon/default.nix
+++ b/pkgs/desktops/cinnamon/default.nix
@@ -13,6 +13,7 @@ lib.makeScope pkgs.newScope (self: with self; {
   });
 
   # blueberry -> pkgs/tools/bluetooth/blueberry/default.nix
+  bulky = callPackage ./bulky {};
   cinnamon-common = callPackage ./cinnamon-common { };
   cinnamon-control-center = callPackage ./cinnamon-control-center { };
   cinnamon-desktop = callPackage ./cinnamon-desktop { };