mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-27 23:50:18 +02:00
01e44ac1f9
This commit removes all references to emacs24 with the exception of emacs24-macports. The two folders in `pkgs/applications/editors` named `emacs-24` and `emacs-24` are consolidated to a new `emacs` folder. Various parts in nixpkgs also referenced `emacs24Packages` (pinned to `emacs24`) explicitly where `emacsPackages` (non-pinned) is more appropriate. These references get fixed by this commit too.
110 lines
4 KiB
Nix
110 lines
4 KiB
Nix
{ stdenv, lib, fetchurl, ncurses, xlibsWrapper, libXaw, libXpm, Xaw3d
|
|
, pkgconfig, gettext, libXft, dbus, libpng, libjpeg, libungif
|
|
, libtiff, librsvg, texinfo, gconf, libxml2, imagemagick, gnutls
|
|
, alsaLib, cairo, acl, gpm, AppKit, CoreWLAN, Kerberos, GSS, ImageIO
|
|
, autoconf, automake
|
|
, withX ? !stdenv.isDarwin
|
|
, withGTK3 ? false, gtk3 ? null
|
|
, withXwidgets ? false, webkitgtk24x ? null, wrapGAppsHook ? null, glib_networking ? null
|
|
, withGTK2 ? true, gtk2
|
|
}:
|
|
|
|
assert (libXft != null) -> libpng != null; # probably a bug
|
|
assert stdenv.isDarwin -> libXaw != null; # fails to link otherwise
|
|
assert withGTK2 -> withX || stdenv.isDarwin;
|
|
assert withGTK3 -> withX || stdenv.isDarwin;
|
|
assert withGTK2 -> !withGTK3 && gtk2 != null;
|
|
assert withGTK3 -> !withGTK2 && gtk3 != null;
|
|
assert withXwidgets -> withGTK3 && webkitgtk24x != null;
|
|
|
|
let
|
|
toolkit =
|
|
if withGTK3 then "gtk3"
|
|
else if withGTK2 then "gtk2"
|
|
else "lucid";
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "emacs-25.1";
|
|
|
|
builder = ./builder.sh;
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnu//emacs/${name}.tar.xz";
|
|
sha256 = "0cwgyiyymnx4xdg99dm2drfxcyhy2jmyf0rkr9fwj9mwwf77kwhr";
|
|
};
|
|
|
|
patches = lib.optionals stdenv.isDarwin [
|
|
./at-fdcwd.patch
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace lisp/international/mule-cmds.el \
|
|
--replace "/usr/share/locale" "${gettext}/share/locale"
|
|
'';
|
|
|
|
buildInputs =
|
|
[ ncurses gconf libxml2 gnutls alsaLib pkgconfig texinfo acl gpm gettext
|
|
autoconf automake ]
|
|
++ lib.optional stdenv.isLinux dbus
|
|
++ lib.optionals withX
|
|
[ xlibsWrapper libXaw Xaw3d libXpm libpng libjpeg libungif libtiff librsvg libXft
|
|
imagemagick gconf ]
|
|
++ lib.optional (withX && withGTK2) gtk2
|
|
++ lib.optional (withX && withGTK3) gtk3
|
|
++ lib.optional (stdenv.isDarwin && withX) cairo
|
|
++ lib.optionals withXwidgets [ webkitgtk24x wrapGAppsHook glib_networking ];
|
|
|
|
propagatedBuildInputs = lib.optionals stdenv.isDarwin [ AppKit GSS ImageIO ];
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
configureFlags = [ "--with-modules" ] ++
|
|
(if stdenv.isDarwin
|
|
then [ "--with-ns" "--disable-ns-self-contained" ]
|
|
else if withX
|
|
then [ "--with-x-toolkit=${toolkit}" "--with-xft" ]
|
|
else [ "--with-x=no" "--with-xpm=no" "--with-jpeg=no" "--with-png=no"
|
|
"--with-gif=no" "--with-tiff=no" ])
|
|
++ lib.optional withXwidgets "--with-xwidgets";
|
|
|
|
NIX_CFLAGS_COMPILE = lib.optionalString (stdenv.isDarwin && withX)
|
|
"-I${cairo.dev}/include/cairo";
|
|
|
|
preBuild = ''
|
|
find . -name '*.elc' -delete
|
|
'';
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share/emacs/site-lisp/
|
|
cp ${./site-start.el} $out/share/emacs/site-lisp/site-start.el
|
|
'' + lib.optionalString stdenv.isDarwin ''
|
|
mkdir -p $out/Applications
|
|
mv nextstep/Emacs.app $out/Applications
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "The extensible, customizable GNU text editor";
|
|
homepage = http://www.gnu.org/software/emacs/;
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [ chaoflow lovek323 peti the-kenny jwiegley ];
|
|
platforms = platforms.all;
|
|
|
|
longDescription = ''
|
|
GNU Emacs is an extensible, customizable text editor—and more. At its
|
|
core is an interpreter for Emacs Lisp, a dialect of the Lisp
|
|
programming language with extensions to support text editing.
|
|
|
|
The features of GNU Emacs include: content-sensitive editing modes,
|
|
including syntax coloring, for a wide variety of file types including
|
|
plain text, source code, and HTML; complete built-in documentation,
|
|
including a tutorial for new users; full Unicode support for nearly all
|
|
human languages and their scripts; highly customizable, using Emacs
|
|
Lisp code or a graphical interface; a large number of extensions that
|
|
add other functionality, including a project planner, mail and news
|
|
reader, debugger interface, calendar, and more. Many of these
|
|
extensions are distributed with GNU Emacs; others are available
|
|
separately.
|
|
'';
|
|
};
|
|
}
|