mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-30 17:10:18 +02:00
40 lines
1.2 KiB
Nix
40 lines
1.2 KiB
Nix
{ stdenv, fetchurl, zlib, apngSupport ? true }:
|
|
|
|
assert zlib != null;
|
|
|
|
let
|
|
patchVersion = "1.6.35";
|
|
patch_src = fetchurl {
|
|
url = "mirror://sourceforge/libpng-apng/libpng-${patchVersion}-apng.patch.gz";
|
|
sha256 = "011fq5wgyz07pfrqs9albixbiksx3agx5nkcf3535gbvhlwv5khq";
|
|
};
|
|
whenPatched = stdenv.lib.optionalString apngSupport;
|
|
|
|
in stdenv.mkDerivation rec {
|
|
name = "libpng" + whenPatched "-apng" + "-${version}";
|
|
version = "1.6.35";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/libpng/libpng-${version}.tar.xz";
|
|
sha256 = "1mxwjf5cdzk7g0y51gl9w3f0j5ypcls05i89kgnifjaqr742x493";
|
|
};
|
|
postPatch = whenPatched "gunzip < ${patch_src} | patch -Np1";
|
|
|
|
outputs = [ "out" "dev" "man" ];
|
|
outputBin = "dev";
|
|
|
|
propagatedBuildInputs = [ zlib ];
|
|
|
|
doCheck = stdenv.hostPlatform == stdenv.buildPlatform;
|
|
|
|
passthru = { inherit zlib; };
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "The official reference implementation for the PNG file format" + whenPatched " with animation patch";
|
|
homepage = http://www.libpng.org/pub/png/libpng.html;
|
|
license = licenses.libpng;
|
|
platforms = platforms.all;
|
|
maintainers = [ maintainers.vcunat maintainers.fuuzetsu ];
|
|
};
|
|
}
|