mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-10-17 11:13:18 +02:00
1e77d0b975
[...] make modules -C /nix/store/h1vzl6bq4wif3m8dd1bw2p3fv4shjg3n-linux-4.14.9-dev/lib/modules/4.14.9/build EXTRA_CFLAGS=-Werror-implicit-function-declaration M=/tmp/nix-build-spl-kernel-2017-11-16-4.14.9.drv-0/source/build /nix/store/h1vzl6bq4wif3m8dd1bw2p3fv4shjg3n-linux-4.14.9-dev/lib/modules/4.14.9/source/Makefile:939: *** "Cannot generate ORC metadata for CONFIG_UNWINDER_ORC=y, please install libelf-dev, libelf-devel or elfutils-libelf-devel". Stop. This patch introduces kernel.moduleBuildDependencies to avoid the logic "stdenv.lib.optional (stdenv.lib.versionAtLeast kernel.version "4.14") libelf" in multiple places. [dezgeg did some minor tweaks on top]
79 lines
2.5 KiB
Nix
79 lines
2.5 KiB
Nix
{ fetchFromGitHub, stdenv, autoreconfHook, coreutils, gawk
|
|
, configFile ? "all"
|
|
|
|
# Kernel dependencies
|
|
, kernel ? null
|
|
}:
|
|
|
|
with stdenv.lib;
|
|
|
|
let
|
|
buildKernel = any (n: n == configFile) [ "kernel" "all" ];
|
|
buildUser = any (n: n == configFile) [ "user" "all" ];
|
|
common = { version
|
|
, sha256
|
|
, rev ? "spl-${version}"
|
|
, broken ? false
|
|
} @ args : stdenv.mkDerivation rec {
|
|
name = "spl-${configFile}-${version}${optionalString buildKernel "-${kernel.version}"}";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "zfsonlinux";
|
|
repo = "spl";
|
|
inherit rev sha256;
|
|
};
|
|
|
|
patches = [ ./const.patch ./install_prefix.patch ];
|
|
|
|
nativeBuildInputs = [ autoreconfHook ] ++ optional (kernel != null) kernel.moduleBuildDependencies;
|
|
|
|
hardeningDisable = [ "pic" ];
|
|
|
|
preConfigure = ''
|
|
substituteInPlace ./module/spl/spl-generic.c --replace /usr/bin/hostid hostid
|
|
substituteInPlace ./module/spl/spl-generic.c --replace "PATH=/sbin:/usr/sbin:/bin:/usr/bin" "PATH=${coreutils}:${gawk}:/bin"
|
|
substituteInPlace ./module/splat/splat-vnode.c --replace "PATH=/sbin:/usr/sbin:/bin:/usr/bin" "PATH=${coreutils}:/bin"
|
|
substituteInPlace ./module/splat/splat-linux.c --replace "PATH=/sbin:/usr/sbin:/bin:/usr/bin" "PATH=${coreutils}:/bin"
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--with-config=${configFile}"
|
|
] ++ optionals buildKernel [
|
|
"--with-linux=${kernel.dev}/lib/modules/${kernel.modDirVersion}/source"
|
|
"--with-linux-obj=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
|
|
];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = {
|
|
description = "Kernel module driver for solaris porting layer (needed by in-kernel zfs)";
|
|
|
|
longDescription = ''
|
|
This kernel module is a porting layer for ZFS to work inside the linux
|
|
kernel.
|
|
'';
|
|
|
|
inherit broken;
|
|
|
|
homepage = http://zfsonlinux.org/;
|
|
platforms = platforms.linux;
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ jcumming wizeman wkennington fpletz globin ];
|
|
};
|
|
};
|
|
in
|
|
assert any (n: n == configFile) [ "kernel" "user" "all" ];
|
|
assert buildKernel -> kernel != null;
|
|
{
|
|
splStable = common {
|
|
version = "0.7.4";
|
|
sha256 = "0vmakqi3zm8ka5cglif45ll2m6ynq7r55mhk8d1rzjkgi191cddh";
|
|
};
|
|
|
|
splUnstable = common {
|
|
version = "2017-11-16";
|
|
rev = "ed19bccfb651843fa208232b3a2d3d22a4152bc8";
|
|
sha256 = "08ihjbf5fhcnhq9zavcwswg9djlbalbx1bil4rcv6i3d617wammb";
|
|
};
|
|
}
|