mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-10-18 11:43:17 +02:00
2e6bf42a22
There ver very many conflicts, basically all due to name -> pname+version. Fortunately, almost everything was auto-resolved by kdiff3, and for now I just fixed up a couple evaluation problems, as verified by the tarball job. There might be some fallback to these conflicts, but I believe it should be minimal. Hydra nixpkgs: ?compare=1538299
57 lines
1.8 KiB
Nix
57 lines
1.8 KiB
Nix
{ stdenv, fetchurl, makeDesktopItem, ffmpeg
|
|
, qmake, qttools, mkDerivation
|
|
, qtbase, qtdeclarative, qtlocation, qtquickcontrols2, qtwebchannel, qtwebengine
|
|
}:
|
|
|
|
mkDerivation rec {
|
|
pname = "clipgrab";
|
|
version = "3.8.4";
|
|
|
|
src = fetchurl {
|
|
sha256 = "0pyrg3rrsd538vnrv6x2frhbq9k2638nzffjsar1p76wxp8fm42s";
|
|
# The .tar.bz2 "Download" link is a binary blob, the source is the .tar.gz!
|
|
url = "https://download.clipgrab.org/${pname}-${version}.tar.gz";
|
|
};
|
|
|
|
buildInputs = [ ffmpeg qtbase qtdeclarative qtlocation qtquickcontrols2 qtwebchannel qtwebengine ];
|
|
nativeBuildInputs = [ qmake qttools ];
|
|
|
|
postPatch = stdenv.lib.optionalString (ffmpeg != null) ''
|
|
substituteInPlace converter_ffmpeg.cpp \
|
|
--replace '"ffmpeg"' '"${ffmpeg.bin}/bin/ffmpeg"' \
|
|
--replace '"ffmpeg ' '"${ffmpeg.bin}/bin/ffmpeg '
|
|
'';
|
|
|
|
qmakeFlags = [ "clipgrab.pro" ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
desktopItem = makeDesktopItem rec {
|
|
name = "clipgrab";
|
|
exec = name;
|
|
icon = name;
|
|
desktopName = "ClipGrab";
|
|
comment = meta.description;
|
|
genericName = "Web video downloader";
|
|
categories = "Qt;AudioVideo;Audio;Video";
|
|
};
|
|
|
|
installPhase = ''
|
|
install -Dm755 clipgrab $out/bin/clipgrab
|
|
install -Dm644 icon.png $out/share/pixmaps/clipgrab.png
|
|
cp -r ${desktopItem}/share/applications $out/share
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Video downloader for YouTube and other sites";
|
|
longDescription = ''
|
|
ClipGrab is a free downloader and converter for YouTube, Vimeo, Metacafe,
|
|
Dailymotion and many other online video sites. It converts downloaded
|
|
videos to MPEG4, MP3 or other formats in just one easy step.
|
|
'';
|
|
homepage = https://clipgrab.org/;
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|