mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-10-01 09:30:20 +02:00
286ef7108f
* vym: 2.6.11 -> 2.7.1 * vym: install man page * vym: fix /usr paths and move data from $out/vym * Change version to 2.7.0 There was some concern that the release tarball 2.7.1 actually contains an in-development snapshot rather than a full release. The consensus seems to be that 2.7.0 should be used instead.
62 lines
1.9 KiB
Nix
62 lines
1.9 KiB
Nix
{ stdenv, mkDerivation, fetchurl, pkgconfig, qmake, qtscript, qtsvg }:
|
|
|
|
mkDerivation rec {
|
|
pname = "vym";
|
|
version = "2.7.0";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/project/vym/${version}/${pname}-${version}.tar.bz2";
|
|
sha256 = "1rnrfqlff7wv6yni8bvff8n90pmn82k82zd4sn1jsx9r1n3qsfkh";
|
|
};
|
|
|
|
# Hardcoded paths scattered about all have form share/vym
|
|
# which is encouraging, although we'll need to patch them (below).
|
|
qmakeFlags = [
|
|
"DATADIR=${placeholder "out"}/share"
|
|
"DOCDIR=${placeholder "out"}/share/doc/vym"
|
|
];
|
|
|
|
postPatch = ''
|
|
for x in \
|
|
exportoofiledialog.cpp \
|
|
main.cpp \
|
|
mainwindow.cpp \
|
|
tex/*.{tex,lyx}; \
|
|
do
|
|
substituteInPlace $x \
|
|
--replace /usr/share/vym $out/share/vym \
|
|
--replace /usr/local/share/vym $out/share/vym \
|
|
--replace /usr/share/doc $out/share/doc/vym
|
|
done
|
|
'';
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig qmake ];
|
|
buildInputs = [ qtscript qtsvg ];
|
|
|
|
postInstall = ''
|
|
install -Dm755 -t $out/share/man/man1 doc/*.1.gz
|
|
'';
|
|
|
|
dontGzipMan = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A mind-mapping software";
|
|
longDescription = ''
|
|
VYM (View Your Mind) is a tool to generate and manipulate maps which show your thoughts.
|
|
Such maps can help you to improve your creativity and effectivity. You can use them
|
|
for time management, to organize tasks, to get an overview over complex contexts,
|
|
to sort your ideas etc.
|
|
|
|
Maps can be drawn by hand on paper or a flip chart and help to structure your thoughs.
|
|
While a tree like structure like shown on this page can be drawn by hand or any drawing software
|
|
vym offers much more features to work with such maps.
|
|
'';
|
|
homepage = http://www.insilmaril.de/vym/;
|
|
license = licenses.gpl2;
|
|
maintainers = [ maintainers.AndersonTorres ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|