mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-29 16:40:18 +02:00
d6876bc879
'gcloud sql connect' command allows to connect to a CloudSQL instance
from a local machine. In order to do so, it starts local
'cloud_sdk_proxy' instance. google-cloud-sdk expects to find one in SDK
root (installed by 'gcloud components') or on the PATH, if SDK is not
correctly installed ('.install' directory is missing).
Since google-cloud-sdk on NixOS is properly installed 'gcloud sql
connect' never looks for 'cloud_sql_proxy' on the PATH and simply
doesn't work at all.
The patch slightly modifies the check by looking not only for
'.install' directory, but for actual 'cloud_sql_proxy' binary before
falling back to the search on the PATH.
With this patch it's now possible to use 'gcloud sql connect' on NixOS,
provided that 'cloud_sql_proxy' is available either in user or system
enviroment (available in nixpkgs).
114 lines
4 KiB
Nix
114 lines
4 KiB
Nix
# Make sure that the "with-gce" flag is set when building `google-cloud-sdk`
|
|
# for GCE hosts. This flag prevents "google-compute-engine" from being a
|
|
# default dependency which is undesirable because this package is
|
|
#
|
|
# 1) available only on GNU/Linux (requires `systemd` in particular)
|
|
# 2) intended only for GCE guests (and is useless elsewhere)
|
|
# 3) used by `google-cloud-sdk` only on GCE guests
|
|
#
|
|
|
|
{ stdenv, lib, fetchurl, makeWrapper, python, openssl, jq, with-gce ? false }:
|
|
|
|
let
|
|
pythonEnv = python.withPackages (p: with p; [
|
|
cffi
|
|
cryptography
|
|
pyopenssl
|
|
crcmod
|
|
] ++ lib.optional (with-gce) google-compute-engine);
|
|
|
|
baseUrl = "https://dl.google.com/dl/cloudsdk/channels/rapid/downloads";
|
|
sources = name: system: {
|
|
x86_64-darwin = {
|
|
url = "${baseUrl}/${name}-darwin-x86_64.tar.gz";
|
|
sha256 = "sha256-aHFwcynt4xQ0T1J+OTSxgttU9W3VFJAqCwmQSdVg8Fk=";
|
|
};
|
|
|
|
x86_64-linux = {
|
|
url = "${baseUrl}/${name}-linux-x86_64.tar.gz";
|
|
sha256 = "sha256-MfldToK7ZfdWZiZnI1qKI1o/dSiUcysxzUkTYMVZ5u4=";
|
|
};
|
|
}.${system};
|
|
|
|
in stdenv.mkDerivation rec {
|
|
pname = "google-cloud-sdk";
|
|
version = "328.0.0";
|
|
|
|
src = fetchurl (sources "${pname}-${version}" stdenv.hostPlatform.system);
|
|
|
|
buildInputs = [ python ];
|
|
|
|
nativeBuildInputs = [ jq makeWrapper ];
|
|
|
|
patches = [
|
|
# For kubectl configs, don't store the absolute path of the `gcloud` binary as it can be garbage-collected
|
|
./gcloud-path.patch
|
|
# Disable checking for updates for the package
|
|
./gsutil-disable-updates.patch
|
|
# Try to use cloud_sql_proxy from SDK only if it actually exists, otherwise, search for one in PATH
|
|
./cloud_sql_proxy_path.patch
|
|
];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/google-cloud-sdk
|
|
cp -R * .install $out/google-cloud-sdk/
|
|
|
|
mkdir -p $out/google-cloud-sdk/lib/surface/{alpha,beta}
|
|
cp ${./alpha__init__.py} $out/google-cloud-sdk/lib/surface/alpha/__init__.py
|
|
cp ${./beta__init__.py} $out/google-cloud-sdk/lib/surface/beta/__init__.py
|
|
|
|
# create wrappers with correct env
|
|
for program in gcloud bq gsutil git-credential-gcloud.sh docker-credential-gcloud; do
|
|
programPath="$out/google-cloud-sdk/bin/$program"
|
|
binaryPath="$out/bin/$program"
|
|
wrapProgram "$programPath" \
|
|
--set CLOUDSDK_PYTHON "${pythonEnv}/bin/python" \
|
|
--prefix PYTHONPATH : "${pythonEnv}/${python.sitePackages}" \
|
|
--prefix PATH : "${openssl.bin}/bin"
|
|
|
|
mkdir -p $out/bin
|
|
ln -s $programPath $binaryPath
|
|
done
|
|
|
|
# disable component updater and update check
|
|
substituteInPlace $out/google-cloud-sdk/lib/googlecloudsdk/core/config.json \
|
|
--replace "\"disable_updater\": false" "\"disable_updater\": true"
|
|
echo "
|
|
[component_manager]
|
|
disable_update_check = true" >> $out/google-cloud-sdk/properties
|
|
|
|
# setup bash completion
|
|
mkdir -p $out/share/bash-completion/completions
|
|
mv $out/google-cloud-sdk/completion.bash.inc $out/share/bash-completion/completions/gcloud.inc
|
|
|
|
# This directory contains compiled mac binaries. We used crcmod from
|
|
# nixpkgs instead.
|
|
rm -r $out/google-cloud-sdk/platform/gsutil/third_party/crcmod \
|
|
$out/google-cloud-sdk/platform/gsutil/third_party/crcmod_osx
|
|
|
|
# remove tests and test data
|
|
find $out -name tests -type d -exec rm -rf '{}' +
|
|
rm $out/google-cloud-sdk/platform/gsutil/gslib/commands/test.py
|
|
|
|
# compact all the JSON
|
|
find $out -name \*.json | while read path; do
|
|
jq -c . $path > $path.min
|
|
mv $path.min $path
|
|
done
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Tools for the google cloud platform";
|
|
longDescription = "The Google Cloud SDK. This package has the programs: gcloud, gsutil, and bq";
|
|
# This package contains vendored dependencies. All have free licenses.
|
|
license = licenses.free;
|
|
homepage = "https://cloud.google.com/sdk/";
|
|
maintainers = with maintainers; [ iammrinal0 pradyuman stephenmw zimbatm ];
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" ];
|
|
};
|
|
}
|