mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-20 12:29:02 +02:00
04a8a09249
This adjusts riemann_c_client to support building with either wolfSSL or GnuTLS (disabled by default, to not introduce a new dependency automatically), and the CLI tool with json-c (enabled by default). Also splits the outputs to `bin`, `dev`, and `out`, enables parallel building, and removes a preBuild step that is no longer necessary, and enables unit tests at build time. On top of this, also correct the license: it is LGPL3+, *not* GPL3. Signed-off-by: Gergely Nagy <me@gergo.csillger.hu>
44 lines
1.2 KiB
Nix
44 lines
1.2 KiB
Nix
{ lib, stdenv, fetchFromGitea, autoreconfHook, check, pkg-config, file, protobufc
|
|
,withWolfSSL ? false, wolfssl
|
|
,withGnuTLS ? false, gnutls
|
|
,withJSON ? true, json_c
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "riemann-c-client";
|
|
version = "2.1.1";
|
|
|
|
src = fetchFromGitea {
|
|
domain = "git.madhouse-project.org";
|
|
owner = "algernon";
|
|
repo = "riemann-c-client";
|
|
rev = "riemann-c-client-${version}";
|
|
hash = "sha256-FIhTT57g2uZBaH3EPNxNUNJn9n+0ZOhI6WMyF+xIr/Q=";
|
|
};
|
|
|
|
outputs = [ "bin" "dev" "out" ];
|
|
|
|
nativeBuildInputs = [ autoreconfHook check pkg-config ];
|
|
buildInputs = [ file protobufc ]
|
|
++ lib.optional withWolfSSL wolfssl
|
|
++ lib.optional withGnuTLS gnutls
|
|
++ lib.optional withJSON json_c
|
|
;
|
|
|
|
configureFlags = []
|
|
++ lib.optional withWolfSSL "--with-tls=wolfssl"
|
|
++ lib.optional withGnuTLS "--with-tls=gnutls"
|
|
;
|
|
|
|
doCheck = true;
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with lib; {
|
|
homepage = "https://git.madhouse-project.org/algernon/riemann-c-client";
|
|
description = "A C client library for the Riemann monitoring system";
|
|
license = licenses.lgpl3Plus;
|
|
maintainers = with maintainers; [ pradeepchhetri ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|