mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-11-05 17:56:46 +01:00
9fb8020e4e
This will probably be mandatory soon, and is a step in the right direction. Removes the deprecated meta.version, and move some meta sections to the end of the file where I should have put them in the first place.
51 lines
1.5 KiB
Nix
51 lines
1.5 KiB
Nix
{ stdenv, fetchurl, libgcrypt, libnl, pkgconfig, pythonPackages, wireless-regdb }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "crda-${version}";
|
|
version = "3.18";
|
|
|
|
src = fetchurl {
|
|
sha256 = "1gydiqgb08d9gbx4l6gv98zg3pljc984m50hmn3ysxcbkxkvkz23";
|
|
url = "http://kernel.org/pub/software/network/crda/crda-${version}.tar.xz";
|
|
};
|
|
|
|
buildInputs = [ libgcrypt libnl ];
|
|
nativeBuildInputs = [
|
|
pkgconfig pythonPackages.m2crypto pythonPackages.python
|
|
];
|
|
|
|
postPatch = ''
|
|
patchShebangs utils/
|
|
substituteInPlace Makefile --replace ldconfig true
|
|
sed -i crda.c \
|
|
-e "/\/usr\/.*\/regulatory.bin/d" \
|
|
-e "s|/lib/crda|${wireless-regdb}/lib/crda|g"
|
|
'';
|
|
|
|
makeFlags = [
|
|
"PREFIX=$(out)"
|
|
"SBINDIR=$(out)/bin/"
|
|
"UDEV_RULE_DIR=$(out)/lib/udev/rules.d/"
|
|
"REG_BIN=${wireless-regdb}/lib/crda/regulatory.bin"
|
|
];
|
|
|
|
buildFlags = [ "all_noverify" ];
|
|
enableParallelBuilding = true;
|
|
|
|
doCheck = true;
|
|
checkTarget = "verify";
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Linux wireless Central Regulatory Domain Agent";
|
|
longDescription = ''
|
|
CRDA acts as the udev helper for communication between the kernel and
|
|
userspace for regulatory compliance. It relies on nl80211 for communication.
|
|
CRDA is intended to be run only through udev communication from the kernel.
|
|
'';
|
|
homepage = http://drvbp1.linux-foundation.org/~mcgrof/rel-html/crda/;
|
|
license = licenses.free; # "copyleft-next 0.3.0", as yet without a web site
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ nckx ];
|
|
};
|
|
}
|