mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-30 00:50:17 +02:00
4651407654
stdenvNoCC should not inject any C++ standard library, just as it doesn't inject any C standard library. stdenv still does, but only indirectly through stdenv.cc. Wrapped clangs can be simplified now that they don't need to worry about clobbering CoreFoundation when replacing the C++ standard library implementation. This generally-good cleanup should assist with debugging some C++ failures in #26805.
78 lines
2.2 KiB
Nix
78 lines
2.2 KiB
Nix
{ lowPrio, newScope, stdenv, targetPlatform, cmake, libstdcxxHook
|
|
, libxml2, python2, isl, fetchurl, overrideCC, wrapCC, ccWrapperFun
|
|
, darwin
|
|
}:
|
|
|
|
let
|
|
callPackage = newScope (self // { inherit stdenv cmake libxml2 python2 isl release_version version fetch; });
|
|
|
|
release_version = "4.0.1";
|
|
version = release_version; # differentiating these is important for rc's
|
|
|
|
fetch = name: sha256: fetchurl {
|
|
url = "https://releases.llvm.org/${release_version}/${name}-${version}.src.tar.xz";
|
|
inherit sha256;
|
|
};
|
|
|
|
compiler-rt_src = fetch "compiler-rt" "0h5lpv1z554szi4r4blbskhwrkd78ir50v3ng8xvk1s86fa7gj53";
|
|
clang-tools-extra_src = fetch "clang-tools-extra" "1dhmp7ccfpr42bmvk3kp37ngjpf3a9m5d4kkpsn7d00hzi7fdl9m";
|
|
|
|
# Add man output without introducing extra dependencies.
|
|
overrideManOutput = drv:
|
|
let drv-manpages = drv.override { enableManpages = true; }; in
|
|
drv // { man = drv-manpages.man; /*outputs = drv.outputs ++ ["man"];*/ };
|
|
|
|
llvm = callPackage ./llvm.nix {
|
|
inherit compiler-rt_src stdenv;
|
|
};
|
|
|
|
clang-unwrapped = callPackage ./clang {
|
|
inherit clang-tools-extra_src stdenv;
|
|
};
|
|
|
|
self = {
|
|
llvm = overrideManOutput llvm;
|
|
clang-unwrapped = overrideManOutput clang-unwrapped;
|
|
|
|
llvm-manpages = lowPrio self.llvm.man;
|
|
clang-manpages = lowPrio self.clang-unwrapped.man;
|
|
|
|
clang = if stdenv.cc.isGNU then self.libstdcxxClang else self.libcxxClang;
|
|
|
|
libstdcxxClang = ccWrapperFun {
|
|
cc = self.clang-unwrapped;
|
|
/* FIXME is this right? */
|
|
inherit (stdenv.cc) bintools libc nativeTools nativeLibc;
|
|
extraPackages = [ libstdcxxHook ];
|
|
};
|
|
|
|
libcxxClang = ccWrapperFun {
|
|
cc = self.clang-unwrapped;
|
|
/* FIXME is this right? */
|
|
inherit (stdenv.cc) bintools libc nativeTools nativeLibc;
|
|
extraPackages = [ self.libcxx self.libcxxabi ];
|
|
};
|
|
|
|
stdenv = stdenv.override (drv: {
|
|
allowedRequisites = null;
|
|
cc = self.clang;
|
|
});
|
|
|
|
libcxxStdenv = stdenv.override (drv: {
|
|
allowedRequisites = null;
|
|
cc = self.libcxxClang;
|
|
});
|
|
|
|
lld = callPackage ./lld.nix {};
|
|
|
|
lldb = callPackage ./lldb.nix {};
|
|
|
|
libcxx = callPackage ./libc++ {};
|
|
|
|
libcxxabi = callPackage ./libc++abi.nix {};
|
|
|
|
openmp = callPackage ./openmp.nix {};
|
|
};
|
|
|
|
in self
|