mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-29 00:20:19 +02:00
468f931f87
Having something like $out/lib/gwenhywfar/plugins/60 when on Nix is a bit pointless, because we won't have something like a central plugin directory which could contain plugins for older library versions. Another reason to strip the effective shared object version is that we really want to avoid the need to track and update the SO version on every single update. This makes it way easier to add support for libchipcard and/or other related packages/plugins. Signed-off-by: aszlig <aszlig@redmoonstudios.org> Cc: @cillianderoiste, @urkud
40 lines
1.2 KiB
Nix
40 lines
1.2 KiB
Nix
{ stdenv, fetchurl, gmp, gwenhywfar, libtool, libxml2, libxslt
|
|
, pkgconfig, xmlsec, zlib
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "aqbanking-${version}";
|
|
version = "5.6.10";
|
|
|
|
src = let
|
|
releaseNum = 206; # Change this on update
|
|
qstring = "package=03&release=${toString releaseNum}&file=01";
|
|
mkURLs = map (base: "${base}/sites/download/download.php?${qstring}");
|
|
in fetchurl {
|
|
name = "${name}.tar.gz";
|
|
urls = mkURLs [ "http://www.aquamaniac.de" "http://www2.aquamaniac.de" ];
|
|
sha256 = "1x0isvpk43rq2zlyyb9p0kgjmqv7yq07vgkiprw3f5sjkykvxw6d";
|
|
};
|
|
|
|
postPatch = ''
|
|
sed -i -e '/^aqbanking_plugindir=/ {
|
|
c aqbanking_plugindir="\''${libdir}/gwenhywfar/plugins"
|
|
}' configure
|
|
'';
|
|
|
|
buildInputs = [ gmp gwenhywfar libtool libxml2 libxslt xmlsec zlib ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
|
|
configureFlags = [ "--with-gwen-dir=${gwenhywfar}" ];
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "An interface to banking tasks, file formats and country information";
|
|
homepage = "http://www2.aquamaniac.de/sites/download/packages.php?package=03&showall=1";
|
|
hydraPlatforms = [];
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ goibhniu urkud ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|