mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-10-01 09:30:20 +02:00
305ac4dade
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/meson/versions. These checks were done: - built on NixOS - /nix/store/r959bxd7pgfd9crp3fagw4x6j6pl105l-meson-0.47.0/bin/meson passed the binary check. - Warning: no invocation of /nix/store/r959bxd7pgfd9crp3fagw4x6j6pl105l-meson-0.47.0/bin/mesonconf had a zero exit code or showed the expected version - Warning: no invocation of /nix/store/r959bxd7pgfd9crp3fagw4x6j6pl105l-meson-0.47.0/bin/mesonintrospect had a zero exit code or showed the expected version - Warning: no invocation of /nix/store/r959bxd7pgfd9crp3fagw4x6j6pl105l-meson-0.47.0/bin/mesontest had a zero exit code or showed the expected version - /nix/store/r959bxd7pgfd9crp3fagw4x6j6pl105l-meson-0.47.0/bin/wraptool passed the binary check. - 2 of 5 passed binary check by having a zero exit code. - 1 of 5 passed binary check by having the new version present in output. - found 0.47.0 with grep in /nix/store/r959bxd7pgfd9crp3fagw4x6j6pl105l-meson-0.47.0 - directory tree listing: https://gist.github.com/921992f726772b72a0e2ccd9591141b1 - du listing: https://gist.github.com/22365bf0c1a1ab300e07e36d205c7eb7
82 lines
2.7 KiB
Nix
82 lines
2.7 KiB
Nix
{ lib, python3Packages, stdenv, ninja, pkgconfig, targetPlatform, writeTextDir, substituteAll }: let
|
|
targetPrefix = lib.optionalString stdenv.isCross
|
|
(targetPlatform.config + "-");
|
|
in python3Packages.buildPythonApplication rec {
|
|
version = "0.47.0";
|
|
pname = "meson";
|
|
|
|
src = python3Packages.fetchPypi {
|
|
inherit pname version;
|
|
sha256 = "1mxsvsw7mg3q4yj8qrkrwv79qwws14qnbihryn2i7504b3r204h6";
|
|
};
|
|
|
|
postFixup = ''
|
|
pushd $out/bin
|
|
# undo shell wrapper as meson tools are called with python
|
|
for i in *; do
|
|
mv ".$i-wrapped" "$i"
|
|
done
|
|
popd
|
|
'';
|
|
|
|
patches = [
|
|
# Upstream insists on not allowing bindir and other dir options
|
|
# outside of prefix for some reason:
|
|
# https://github.com/mesonbuild/meson/issues/2561
|
|
# We remove the check so multiple outputs can work sanely.
|
|
./allow-dirs-outside-of-prefix.patch
|
|
|
|
# Unlike libtool, vanilla Meson does not pass any information
|
|
# about the path library will be installed to to g-ir-scanner,
|
|
# breaking the GIR when path other than ${!outputLib}/lib is used.
|
|
# We patch Meson to add a --fallback-library-path argument with
|
|
# library install_dir to g-ir-scanner.
|
|
./gir-fallback-path.patch
|
|
|
|
# In common distributions, RPATH is only needed for internal libraries so
|
|
# meson removes everything else. With Nix, the locations of libraries
|
|
# are not as predictable, therefore we need to keep them in the RPATH.
|
|
# At the moment we are keeping the paths starting with /nix/store.
|
|
# https://github.com/NixOS/nixpkgs/issues/31222#issuecomment-365811634
|
|
(substituteAll {
|
|
src = ./fix-rpath.patch;
|
|
inherit (builtins) storeDir;
|
|
})
|
|
];
|
|
|
|
setupHook = ./setup-hook.sh;
|
|
|
|
crossFile = writeTextDir "cross-file.conf" ''
|
|
[binaries]
|
|
c = '${targetPrefix}cc'
|
|
cpp = '${targetPrefix}c++'
|
|
ar = '${targetPrefix}ar'
|
|
strip = '${targetPrefix}strip'
|
|
pkgconfig = 'pkg-config'
|
|
|
|
[properties]
|
|
needs_exe_wrapper = true
|
|
|
|
[host_machine]
|
|
system = '${targetPlatform.parsed.kernel.name}'
|
|
cpu_family = '${targetPlatform.parsed.cpu.family}'
|
|
cpu = '${targetPlatform.parsed.cpu.name}'
|
|
endian = ${if targetPlatform.isLittleEndian then "'little'" else "'big'"}
|
|
'';
|
|
|
|
# 0.45 update enabled tests but they are failing
|
|
doCheck = false;
|
|
# checkInputs = [ ninja pkgconfig ];
|
|
# checkPhase = "python ./run_project_tests.py";
|
|
|
|
inherit (stdenv) cc isCross;
|
|
|
|
meta = with lib; {
|
|
homepage = http://mesonbuild.com;
|
|
description = "SCons-like build system that use python as a front-end language and Ninja as a building backend";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ mbe rasendubi ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|