mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-11-05 17:56:46 +01:00
76999cc40e
This makes the command ‘nix-env -qa -f. --arg config '{skipAliases =
true;}'’ work in Nixpkgs.
Misc...
- qtikz: use libsForQt5.callPackage
This ensures we get the right poppler.
- rewrites:
docbook5_xsl -> docbook_xsl_ns
docbook_xml_xslt -> docbook_xsl
diffpdf: fixup
76 lines
2.3 KiB
Nix
76 lines
2.3 KiB
Nix
{ stdenv, fetchurl, pkgconfig, dbus, nettle
|
|
, libidn, libnetfilter_conntrack, fetchpatch }:
|
|
|
|
with stdenv.lib;
|
|
let
|
|
copts = concatStringsSep " " ([
|
|
"-DHAVE_IDN"
|
|
"-DHAVE_DNSSEC"
|
|
] ++ optionals stdenv.isLinux [
|
|
"-DHAVE_DBUS"
|
|
"-DHAVE_CONNTRACK"
|
|
]);
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "dnsmasq-2.79";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.thekelleys.org.uk/dnsmasq/${name}.tar.xz";
|
|
sha256 = "07w6cw706yyahwvbvslhkrbjf2ynv567cgy9pal8bz8lrbsp9bbq";
|
|
};
|
|
|
|
preBuild = ''
|
|
makeFlagsArray=("COPTS=${copts}")
|
|
'';
|
|
|
|
makeFlags = [
|
|
"DESTDIR="
|
|
"BINDIR=$(out)/bin"
|
|
"MANDIR=$(out)/man"
|
|
"LOCALEDIR=$(out)/share/locale"
|
|
];
|
|
|
|
hardeningEnable = [ "pie" ];
|
|
|
|
postBuild = optionalString stdenv.isLinux ''
|
|
make -C contrib/lease-tools
|
|
'';
|
|
|
|
# XXX: Does the systemd service definition really belong here when our NixOS
|
|
# module can create it in Nix-land?
|
|
postInstall = ''
|
|
install -Dm644 trust-anchors.conf $out/share/dnsmasq/trust-anchors.conf
|
|
'' + optionalString stdenv.isDarwin ''
|
|
install -Dm644 contrib/MacOSX-launchd/uk.org.thekelleys.dnsmasq.plist \
|
|
$out/Library/LaunchDaemons/uk.org.thekelleys.dnsmasq.plist
|
|
substituteInPlace $out/Library/LaunchDaemons/uk.org.thekelleys.dnsmasq.plist \
|
|
--replace "/usr/local/sbin" "$out/bin"
|
|
'' + optionalString stdenv.isLinux ''
|
|
install -Dm644 dbus/dnsmasq.conf $out/etc/dbus-1/system.d/dnsmasq.conf
|
|
install -Dm755 contrib/lease-tools/dhcp_lease_time $out/bin/dhcp_lease_time
|
|
install -Dm755 contrib/lease-tools/dhcp_release $out/bin/dhcp_release
|
|
install -Dm755 contrib/lease-tools/dhcp_release6 $out/bin/dhcp_release6
|
|
|
|
mkdir -p $out/share/dbus-1/system-services
|
|
cat <<END > $out/share/dbus-1/system-services/uk.org.thekelleys.dnsmasq.service
|
|
[D-BUS Service]
|
|
Name=uk.org.thekelleys.dnsmasq
|
|
Exec=$out/bin/dnsmasq -k -1
|
|
User=root
|
|
SystemdService=dnsmasq.service
|
|
END
|
|
'';
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [ nettle libidn ]
|
|
++ optionals stdenv.isLinux [ dbus libnetfilter_conntrack ];
|
|
|
|
meta = {
|
|
description = "An integrated DNS, DHCP and TFTP server for small networks";
|
|
homepage = http://www.thekelleys.org.uk/dnsmasq/doc.html;
|
|
license = licenses.gpl2;
|
|
platforms = with platforms; linux ++ darwin;
|
|
maintainers = with maintainers; [ eelco fpletz ];
|
|
};
|
|
}
|