mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-30 00:50:17 +02:00
3ec81ae27e
On darwin llvmPackages is built using python-boot to avoid dependencies in the stdenv, but we can't and shouldn't use that when building the manpages since it depends on python packages.
75 lines
2.3 KiB
Nix
75 lines
2.3 KiB
Nix
{ lowPrio, newScope, pkgs, stdenv, cmake, libstdcxxHook
|
|
, libxml2, python, isl, fetchurl, overrideCC, wrapCCWith
|
|
, buildLlvmTools # tools, but from the previous stage, for cross
|
|
, targetLlvmLibraries # libraries, but from the next stage, for cross
|
|
}:
|
|
|
|
let
|
|
release_version = "4.0.1";
|
|
version = release_version; # differentiating these is important for rc's
|
|
|
|
fetch = name: sha256: fetchurl {
|
|
url = "https://releases.llvm.org/${release_version}/${name}-${version}.src.tar.xz";
|
|
inherit sha256;
|
|
};
|
|
|
|
compiler-rt_src = fetch "compiler-rt" "0h5lpv1z554szi4r4blbskhwrkd78ir50v3ng8xvk1s86fa7gj53";
|
|
clang-tools-extra_src = fetch "clang-tools-extra" "1dhmp7ccfpr42bmvk3kp37ngjpf3a9m5d4kkpsn7d00hzi7fdl9m";
|
|
|
|
tools = stdenv.lib.makeExtensible (tools: let
|
|
callPackage = newScope (tools // { inherit stdenv cmake libxml2 python isl release_version version fetch; });
|
|
in {
|
|
|
|
llvm = callPackage ./llvm.nix {
|
|
inherit compiler-rt_src;
|
|
};
|
|
clang-unwrapped = callPackage ./clang {
|
|
inherit clang-tools-extra_src;
|
|
};
|
|
|
|
llvm-manpages = lowPrio (tools.llvm.override {
|
|
enableManpages = true;
|
|
python = pkgs.python; # don't use python-boot
|
|
});
|
|
|
|
clang-manpages = lowPrio (tools.clang-unwrapped.override {
|
|
enableManpages = true;
|
|
python = pkgs.python; # don't use python-boot
|
|
});
|
|
|
|
libclang = tools.clang-unwrapped.lib;
|
|
|
|
clang = if stdenv.cc.isGNU then tools.libstdcxxClang else tools.libcxxClang;
|
|
|
|
libstdcxxClang = wrapCCWith {
|
|
cc = tools.clang-unwrapped;
|
|
extraPackages = [ libstdcxxHook ];
|
|
};
|
|
|
|
libcxxClang = wrapCCWith {
|
|
cc = tools.clang-unwrapped;
|
|
extraPackages = [ targetLlvmLibraries.libcxx targetLlvmLibraries.libcxxabi ];
|
|
};
|
|
|
|
lld = callPackage ./lld.nix {};
|
|
|
|
lldb = callPackage ./lldb.nix {};
|
|
});
|
|
|
|
libraries = stdenv.lib.makeExtensible (libraries: let
|
|
callPackage = newScope (libraries // buildLlvmTools // { inherit stdenv cmake libxml2 python isl release_version version fetch; });
|
|
in {
|
|
|
|
stdenv = overrideCC stdenv buildLlvmTools.clang;
|
|
|
|
libcxxStdenv = overrideCC stdenv buildLlvmTools.libcxxClang;
|
|
|
|
libcxx = callPackage ./libc++ {};
|
|
|
|
libcxxabi = callPackage ./libc++abi.nix {};
|
|
|
|
openmp = callPackage ./openmp.nix {};
|
|
});
|
|
|
|
in { inherit tools libraries; } // libraries // tools
|