mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-11-06 18:26:45 +01:00
91340aeea8
This was broken in `haskellPackages` for a long time, but it’s back! Time to give it a place in the toplevel and a prope) treatment: * Semi-static binary * Remove all references to `Paths_` modules of dependencies * gitit tries very hard to have a runtime dependency on GHC, disable that by default. Also added myself as a maintainer, let’s try to keep this working from now on. Fixes https://github.com/NixOS/nixpkgs/issues/32377
62 lines
2 KiB
Nix
62 lines
2 KiB
Nix
{ lib, haskellPackages, haskell, removeReferencesTo
|
||
# “Plugins” are a fancy way of saying gitit will invoke
|
||
# GHC at *runtime*, which in turn makes it pull GHC
|
||
# into its runtime closure. Only enable if you really need
|
||
# that feature. But if you do you’ll want to use gitit
|
||
# as a library anyway.
|
||
, pluginSupport ? false
|
||
}:
|
||
|
||
# this is similar to what we do with the pandoc executable
|
||
|
||
let
|
||
plain = haskellPackages.gitit;
|
||
plugins =
|
||
if pluginSupport
|
||
then plain
|
||
else haskell.lib.disableCabalFlag plain "plugins";
|
||
static = haskell.lib.justStaticExecutables plugins;
|
||
|
||
in
|
||
(haskell.lib.overrideCabal static (drv: {
|
||
buildTools = (drv.buildTools or []) ++ [ removeReferencesTo ];
|
||
})).overrideAttrs (drv: {
|
||
|
||
# These libraries are still referenced, because they generate
|
||
# a `Paths_*` module for figuring out their version.
|
||
# The `Paths_*` module is generated by Cabal, and contains the
|
||
# version, but also paths to e.g. the data directories, which
|
||
# lead to a transitive runtime dependency on the whole GHC distribution.
|
||
# This should ideally be fixed in haskellPackages (or even Cabal),
|
||
# but a minimal gitit is important enough to patch it manually.
|
||
disallowedReferences = [
|
||
haskellPackages.pandoc-types
|
||
haskellPackages.HTTP
|
||
haskellPackages.pandoc
|
||
haskellPackages.happstack-server
|
||
haskellPackages.filestore
|
||
];
|
||
postInstall = ''
|
||
remove-references-to \
|
||
-t ${haskellPackages.pandoc-types} \
|
||
$out/bin/gitit
|
||
remove-references-to \
|
||
-t ${haskellPackages.HTTP} \
|
||
$out/bin/gitit
|
||
remove-references-to \
|
||
-t ${haskellPackages.pandoc} \
|
||
$out/bin/gitit
|
||
remove-references-to \
|
||
-t ${haskellPackages.happstack-server} \
|
||
$out/bin/gitit
|
||
remove-references-to \
|
||
-t ${haskellPackages.filestore} \
|
||
$out/bin/gitit
|
||
'';
|
||
|
||
meta = drv.meta // {
|
||
maintainers = drv.meta.maintainers or []
|
||
++ [ lib.maintainers.Profpatsch ];
|
||
};
|
||
})
|