mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-21 12:59:04 +02:00
15f1369b95
This reverts commitsf5483464d5and6b9583e5e1. Ideally, we shouldn't cause friction for users that bump `stateVersion`, and I'd consider having to switch and/or manually hardcode a UID/GID to supress the warning friction. I think it'd be more beneficial to, in this rare case of an ID being missed, just let it be until more discussion happens surrounding this overall issue. See https://github.com/NixOS/nixpkgs/pull/217785 for more context.
79 lines
2.1 KiB
Nix
79 lines
2.1 KiB
Nix
{ config, lib, pkgs, utils, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.systemd.coredump;
|
|
systemd = config.systemd.package;
|
|
in {
|
|
options = {
|
|
systemd.coredump.enable = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = lib.mdDoc ''
|
|
Whether core dumps should be processed by
|
|
{command}`systemd-coredump`. If disabled, core dumps
|
|
appear in the current directory of the crashing process.
|
|
'';
|
|
};
|
|
|
|
systemd.coredump.extraConfig = mkOption {
|
|
default = "";
|
|
type = types.lines;
|
|
example = "Storage=journal";
|
|
description = lib.mdDoc ''
|
|
Extra config options for systemd-coredump. See coredump.conf(5) man page
|
|
for available options.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkMerge [
|
|
|
|
(mkIf cfg.enable {
|
|
systemd.additionalUpstreamSystemUnits = [
|
|
"systemd-coredump.socket"
|
|
"systemd-coredump@.service"
|
|
];
|
|
|
|
environment.etc = {
|
|
"systemd/coredump.conf".text =
|
|
''
|
|
[Coredump]
|
|
${cfg.extraConfig}
|
|
'';
|
|
|
|
# install provided sysctl snippets
|
|
"sysctl.d/50-coredump.conf".source =
|
|
# Fix systemd-coredump error caused by truncation of `kernel.core_pattern`
|
|
# when the `systemd` derivation name is too long. This works by substituting
|
|
# the path to `systemd` with a symlink that has a constant-length path.
|
|
#
|
|
# See: https://github.com/NixOS/nixpkgs/issues/213408
|
|
pkgs.substitute {
|
|
src = "${systemd}/example/sysctl.d/50-coredump.conf";
|
|
replacements = [
|
|
"--replace"
|
|
"${systemd}"
|
|
"${pkgs.symlinkJoin { name = "systemd"; paths = [ systemd ]; }}"
|
|
];
|
|
};
|
|
|
|
"sysctl.d/50-default.conf".source = "${systemd}/example/sysctl.d/50-default.conf";
|
|
};
|
|
|
|
users.users.systemd-coredump = {
|
|
uid = config.ids.uids.systemd-coredump;
|
|
group = "systemd-coredump";
|
|
};
|
|
users.groups.systemd-coredump = {};
|
|
})
|
|
|
|
(mkIf (!cfg.enable) {
|
|
boot.kernel.sysctl."kernel.core_pattern" = mkDefault "core";
|
|
})
|
|
|
|
];
|
|
|
|
}
|