mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-23 05:35:50 +02:00
72 lines
1.9 KiB
Nix
72 lines
1.9 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, fetchzip, installShellFiles, stdenv }:
|
|
|
|
let
|
|
version = "0.34.0";
|
|
sha256 = "1znxhjqvch0z0s98v3hvvh1pa3nlv0l6qhlm0f61z64srz3i5d1k";
|
|
manifestsSha256 = "1fchzr7fb894hdya9bbh59avqsa66wcz06fck60wmwpc93m64cqs";
|
|
|
|
manifests = fetchzip {
|
|
url =
|
|
"https://github.com/fluxcd/flux2/releases/download/v${version}/manifests.tar.gz";
|
|
sha256 = manifestsSha256;
|
|
stripRoot = false;
|
|
};
|
|
|
|
in buildGoModule rec {
|
|
pname = "fluxcd";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "fluxcd";
|
|
repo = "flux2";
|
|
rev = "v${version}";
|
|
inherit sha256;
|
|
};
|
|
|
|
vendorSha256 = "sha256-0oHcitczG+sW9mkwxY6hCdR2ASpat2XQ+IsLAiqCUb8=";
|
|
|
|
postUnpack = ''
|
|
cp -r ${manifests} source/cmd/flux/manifests
|
|
'';
|
|
|
|
patches = [ ./patches/disable-tests-ssh_key.patch ];
|
|
|
|
ldflags = [ "-s" "-w" "-X main.VERSION=${version}" ];
|
|
|
|
subPackages = [ "cmd/flux" ];
|
|
|
|
# Required to workaround test error:
|
|
# panic: mkdir /homeless-shelter: permission denied
|
|
HOME = "$TMPDIR";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
doInstallCheck = true;
|
|
installCheckPhase = ''
|
|
$out/bin/flux --version | grep ${version} > /dev/null
|
|
'';
|
|
|
|
postInstall = lib.optionalString (stdenv.hostPlatform == stdenv.buildPlatform) ''
|
|
for shell in bash fish zsh; do
|
|
$out/bin/flux completion $shell > flux.$shell
|
|
installShellCompletion flux.$shell
|
|
done
|
|
'';
|
|
|
|
passthru.updateScript = ./update.sh;
|
|
|
|
meta = with lib; {
|
|
description =
|
|
"Open and extensible continuous delivery solution for Kubernetes";
|
|
longDescription = ''
|
|
Flux is a tool for keeping Kubernetes clusters in sync
|
|
with sources of configuration (like Git repositories), and automating
|
|
updates to configuration when there is new code to deploy.
|
|
'';
|
|
homepage = "https://fluxcd.io";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ bryanasdev000 jlesquembre superherointj ];
|
|
mainProgram = "flux";
|
|
};
|
|
}
|