mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-30 00:50:17 +02:00
f431e20549
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/sudo/versions. These checks were done: - built on NixOS - ran ‘/nix/store/d2g0ybmppcar8k38jjiqqdz8s3knwrrm-sudo-1.8.23/bin/cvtsudoers -h’ got 0 exit code - ran ‘/nix/store/d2g0ybmppcar8k38jjiqqdz8s3knwrrm-sudo-1.8.23/bin/cvtsudoers --help’ got 0 exit code - ran ‘/nix/store/d2g0ybmppcar8k38jjiqqdz8s3knwrrm-sudo-1.8.23/bin/sudoreplay -h’ got 0 exit code - ran ‘/nix/store/d2g0ybmppcar8k38jjiqqdz8s3knwrrm-sudo-1.8.23/bin/sudoreplay --help’ got 0 exit code - ran ‘/nix/store/d2g0ybmppcar8k38jjiqqdz8s3knwrrm-sudo-1.8.23/bin/sudoreplay -V’ and found version 1.8.23 - ran ‘/nix/store/d2g0ybmppcar8k38jjiqqdz8s3knwrrm-sudo-1.8.23/bin/sudoreplay --version’ and found version 1.8.23 - ran ‘/nix/store/d2g0ybmppcar8k38jjiqqdz8s3knwrrm-sudo-1.8.23/bin/visudo -h’ got 0 exit code - ran ‘/nix/store/d2g0ybmppcar8k38jjiqqdz8s3knwrrm-sudo-1.8.23/bin/visudo --help’ got 0 exit code - found 1.8.23 with grep in /nix/store/d2g0ybmppcar8k38jjiqqdz8s3knwrrm-sudo-1.8.23 - directory tree listing: https://gist.github.com/4d6cfc75cde31a340e8a41bf3d969564
84 lines
2.1 KiB
Nix
84 lines
2.1 KiB
Nix
{ stdenv, fetchurl, coreutils, pam, groff, sssd
|
|
, sendmailPath ? "/run/wrappers/bin/sendmail"
|
|
, withInsults ? false
|
|
, withSssd ? false
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "sudo-1.8.23";
|
|
|
|
src = fetchurl {
|
|
urls =
|
|
[ "ftp://ftp.sudo.ws/pub/sudo/${name}.tar.gz"
|
|
"ftp://ftp.sudo.ws/pub/sudo/OLD/${name}.tar.gz"
|
|
];
|
|
sha256 = "0yg62wq8rcrbr7qvh3wgfg2g4bwanbi50cr2lf2cfyy8dydx4qyq";
|
|
};
|
|
|
|
prePatch = ''
|
|
# do not set sticky bit in nix store
|
|
substituteInPlace src/Makefile.in --replace 04755 0755
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--with-env-editor"
|
|
"--with-editor=/run/current-system/sw/bin/nano"
|
|
"--with-rundir=/run/sudo"
|
|
"--with-vardir=/var/db/sudo"
|
|
"--with-logpath=/var/log/sudo.log"
|
|
"--with-iologdir=/var/log/sudo-io"
|
|
"--with-sendmail=${sendmailPath}"
|
|
"--enable-tmpfiles.d=no"
|
|
] ++ stdenv.lib.optional withInsults [
|
|
"--with-insults"
|
|
"--with-all-insults"
|
|
] ++ stdenv.lib.optional withSssd [
|
|
"--with-sssd"
|
|
"--with-sssd-lib=${sssd}/lib"
|
|
];
|
|
|
|
configureFlagsArray = [
|
|
"--with-passprompt=[sudo] password for %p: " # intentional trailing space
|
|
];
|
|
|
|
postConfigure =
|
|
''
|
|
cat >> pathnames.h <<'EOF'
|
|
#undef _PATH_MV
|
|
#define _PATH_MV "${coreutils}/bin/mv"
|
|
EOF
|
|
makeFlags="install_uid=$(id -u) install_gid=$(id -g)"
|
|
installFlags="sudoers_uid=$(id -u) sudoers_gid=$(id -g) sysconfdir=$out/etc rundir=$TMPDIR/dummy vardir=$TMPDIR/dummy"
|
|
'';
|
|
|
|
nativeBuildInputs = [ groff ];
|
|
buildInputs = [ pam ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
postInstall =
|
|
''
|
|
rm -f $out/share/doc/sudo/ChangeLog
|
|
'';
|
|
|
|
meta = {
|
|
description = "A command to run commands as root";
|
|
|
|
longDescription =
|
|
''
|
|
Sudo (su "do") allows a system administrator to delegate
|
|
authority to give certain users (or groups of users) the ability
|
|
to run some (or all) commands as root or another user while
|
|
providing an audit trail of the commands and their arguments.
|
|
'';
|
|
|
|
homepage = https://www.sudo.ws/;
|
|
|
|
license = https://www.sudo.ws/sudo/license.html;
|
|
|
|
maintainers = [ stdenv.lib.maintainers.eelco ];
|
|
|
|
platforms = stdenv.lib.platforms.linux;
|
|
};
|
|
}
|