mirror of
https://github.com/SebastianWendel/nixpkgs.git
synced 2024-09-22 21:30:45 +02:00
1d6af3f762
They started failing after gnupg: 2.4.0 -> 2.4.1: T350-crypto: Testing PGP/MIME signature verification and decryption PASS emacs delivery of signed message via fcc PASS emacs delivery of signed message via fcc and smtp PASS signed part content-type indexing PASS signature verification PASS detection of modified signed contents PASS corrupted pgp/mime signature PASS signature verification without full user ID validity PASS signature verification with signer key unavailable FATAL: /build/notmuch-0.37/test/T350-crypto.sh: interrupted by signal 15 [...] T357-index-decryption: Testing indexing decrypted mail FATAL: /build/notmuch-0.37/test/T357-index-decryption.sh: interrupted by signal 15 I hope the failures don't signify a real issue. There's also gnupg22 which would pass these tests, but it's currently marked as vulnerable (transitively).
125 lines
3.8 KiB
Nix
125 lines
3.8 KiB
Nix
{ fetchurl, lib, stdenv
|
|
, pkg-config, gnupg
|
|
, xapian, gmime3, talloc, zlib
|
|
, doxygen, perl, texinfo
|
|
, notmuch
|
|
, pythonPackages
|
|
, emacs
|
|
, ruby
|
|
, testers
|
|
, which, dtach, openssl, bash, gdb, man
|
|
, withEmacs ? true
|
|
, withRuby ? true
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "notmuch";
|
|
version = "0.37";
|
|
|
|
src = fetchurl {
|
|
url = "https://notmuchmail.org/releases/notmuch-${version}.tar.xz";
|
|
sha256 = "sha256-DnZt8ot4v064I1Ymqx9S8E8eNmZJMlqM6NPJCGAnhvY=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
doxygen # (optional) api docs
|
|
pythonPackages.sphinx # (optional) documentation -> doc/INSTALL
|
|
texinfo # (optional) documentation -> doc/INSTALL
|
|
pythonPackages.cffi
|
|
] ++ lib.optional withEmacs emacs
|
|
++ lib.optional withRuby ruby;
|
|
|
|
buildInputs = [
|
|
gnupg # undefined dependencies
|
|
xapian gmime3 talloc zlib # dependencies described in INSTALL
|
|
perl
|
|
pythonPackages.python
|
|
] ++ lib.optional withRuby ruby;
|
|
|
|
postPatch = ''
|
|
patchShebangs configure test/
|
|
|
|
substituteInPlace lib/Makefile.local \
|
|
--replace '-install_name $(libdir)' "-install_name $out/lib"
|
|
|
|
# do not override CFLAGS of the Makefile created by mkmf
|
|
substituteInPlace bindings/Makefile.local \
|
|
--replace 'CFLAGS="$(CFLAGS) -pipe -fno-plt -fPIC"' ""
|
|
'' + lib.optionalString withEmacs ''
|
|
substituteInPlace emacs/notmuch-emacs-mua \
|
|
--replace 'EMACS:-emacs' 'EMACS:-${emacs}/bin/emacs' \
|
|
--replace 'EMACSCLIENT:-emacsclient' 'EMACSCLIENT:-${emacs}/bin/emacsclient'
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--zshcompletiondir=${placeholder "out"}/share/zsh/site-functions"
|
|
"--bashcompletiondir=${placeholder "out"}/share/bash-completion/completions"
|
|
"--infodir=${placeholder "info"}/share/info"
|
|
] ++ lib.optional (!withEmacs) "--without-emacs"
|
|
++ lib.optional withEmacs "--emacslispdir=${placeholder "emacs"}/share/emacs/site-lisp"
|
|
++ lib.optional (!withRuby) "--without-ruby";
|
|
|
|
# Notmuch doesn't use autoconf and consequently doesn't tag --bindir and
|
|
# friends
|
|
setOutputFlags = false;
|
|
enableParallelBuilding = true;
|
|
makeFlags = [ "V=1" ];
|
|
|
|
postConfigure = ''
|
|
mkdir ${placeholder "bindingconfig"}
|
|
cp bindings/python-cffi/_notmuch_config.py ${placeholder "bindingconfig"}/
|
|
'';
|
|
|
|
outputs = [ "out" "man" "info" "bindingconfig" ]
|
|
++ lib.optional withEmacs "emacs"
|
|
++ lib.optional withRuby "ruby";
|
|
|
|
preCheck = let
|
|
test-database = fetchurl {
|
|
url = "https://notmuchmail.org/releases/test-databases/database-v1.tar.xz";
|
|
sha256 = "1lk91s00y4qy4pjh8638b5lfkgwyl282g1m27srsf7qfn58y16a2";
|
|
};
|
|
in ''
|
|
mkdir -p test/test-databases
|
|
ln -s ${test-database} test/test-databases/database-v1.tar.xz
|
|
''
|
|
# Issues since gnupg: 2.4.0 -> 2.4.1
|
|
+ ''
|
|
rm test/{T350-crypto,T357-index-decryption}.sh
|
|
'';
|
|
|
|
doCheck = !stdenv.hostPlatform.isDarwin && (lib.versionAtLeast gmime3.version "3.0.3");
|
|
checkTarget = "test";
|
|
nativeCheckInputs = [
|
|
which dtach openssl bash
|
|
gdb man emacs
|
|
];
|
|
|
|
installTargets = [ "install" "install-man" "install-info" ];
|
|
|
|
postInstall = lib.optionalString withEmacs ''
|
|
moveToOutput bin/notmuch-emacs-mua $emacs
|
|
'' + lib.optionalString withRuby ''
|
|
make -C bindings/ruby install \
|
|
vendordir=$ruby/lib/ruby \
|
|
SHELL=$SHELL \
|
|
$makeFlags "''${makeFlagsArray[@]}" \
|
|
$installFlags "''${installFlagsArray[@]}"
|
|
'';
|
|
|
|
passthru = {
|
|
pythonSourceRoot = "notmuch-${version}/bindings/python";
|
|
tests.version = testers.testVersion { package = notmuch; };
|
|
inherit version;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Mail indexer";
|
|
homepage = "https://notmuchmail.org/";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [ flokli puckipedia ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|